home *** CD-ROM | disk | FTP | other *** search
/ ShareWare OnLine 2 / ShareWare OnLine Volume 2 (CMS Software)(1993).iso / bbs_soft / mrun210.zip / MRUN210F.WAS < prev    next >
Text File  |  1993-04-28  |  11KB  |  459 lines
  1. ;MailRun v2.10:  Part F, othercmds
  2. ;1992-1993 Gerald P. Sully, all rights reserved.
  3.  
  4. #comment
  5. **************************************************************************
  6. **************************************************************************
  7. * 
  8. * This file is a grab bag of routines for the following:
  9. * adding an item to Get or Send Mail; adding an item to send a
  10. * command; adding an item to execute a script; displaying the 
  11. * "About MailRun" dialog box.  The appropriate routine is 
  12. * selected with a FLAG.
  13. * 
  14. **************************************************************************
  15. **************************************************************************
  16. #endcomment
  17.  
  18. #define MRUN210F
  19.  
  20. #include "mrun210.h"
  21.  
  22. string Command, ScriptName, ScriptList, MRunIcons
  23. integer GetSendRadio, IconIndex
  24.  
  25.  
  26. #comment
  27. *********************************************************************
  28. * 
  29. * MAIN()
  30. * 
  31. * Calls checkchild(), addgetmail(), addsendcommand(), 
  32. * adddoscript(), showabout(), menudim()
  33. * 
  34. * Calls the appropriate function based on the value of
  35. * FLAGS.
  36. * 
  37. *********************************************************************
  38. #endcomment
  39.  
  40. proc main
  41. integer cmdstatus
  42.     menudim()
  43.     checkchild()
  44.     findfirst MailRun
  45.     MailRunTrunc = $FILENAME
  46.     cmdstatus = FLAGS & (AGM + CMD + SCR + ABT)
  47.     switch cmdstatus
  48.         case AGM
  49.             addgetmail()
  50.         endcase
  51.         case CMD
  52.             addsendcommand()
  53.         endcase
  54.         case SCR
  55.             adddoscript()
  56.         endcase
  57.         case ABT
  58.             showabout()
  59.         endcase
  60.     endswitch
  61. endproc
  62.  
  63.  
  64. #comment
  65. *********************************************************************
  66. * 
  67. * ADDGETMAIL()
  68. * 
  69. * Called by main()
  70. * 
  71. * Calls getbbsi(), getitemi(), getbbscoord(), getitemcoord(),
  72. * getmailbox(), gettaskstring(), makebbslist(),
  73. * checkperm(), insertitem(), interfaceon()
  74. * 
  75. * Adds a GetMail item to the mailrun.
  76. * 
  77. *********************************************************************
  78. #endcomment
  79.  
  80. proc addgetmail
  81. string GetMailString, StatString
  82. string GetSendMail
  83. string Perm
  84. integer dialogstatus
  85. integer i, j
  86.     i = getbbsi()
  87.     j = getitemi()
  88.     makebbslist()
  89.     getmailbox()
  90.     statmsg ""
  91.     interfaceon()
  92.     while 1
  93.         dialogstatus = $DIALOG
  94.         switch dialogstatus
  95.             case 10
  96.                 ;User selected "Add"
  97.                 if GetSendRadio == 1
  98.                     GetSendMail = "GetMail"
  99.                     strfmt StatString "Added to %s:  `"Get QWK Packet`"" BBS
  100.                 else
  101.                     GetSendMail = "SendMail"
  102.                     strfmt StatString "Added to %s:  `"Send REP Packet`"" BBS
  103.                 endif
  104.                 Perm = checkperm()
  105.                 strfmt GetMailString "1,%s,%s" Perm GetSendMail
  106.                 ;Update MAILRUN.INI, task list
  107.                 j++
  108.                 insertitem(j, GetMailString)
  109.                 TaskItem = gettaskstring(i, j)
  110.                 statmsg StatString
  111.             endcase
  112.             case 11
  113.                 ;User selected "Done"
  114.                 exit
  115.             endcase
  116.             case 170
  117.                 ;User changed BBS with combobox
  118.                 i = getbbscoord()
  119.                 j = getitemcoord()
  120.                 TaskItem = gettaskstring(i, 0)
  121.             endcase
  122.         endswitch
  123.     endwhile
  124. endproc
  125.  
  126.  
  127. #comment
  128. *********************************************************************
  129. * 
  130. * GETMAILBOX()
  131. * 
  132. * Called by addgetmail()
  133. * 
  134. * Displays the Get/Send Mail dialog box.
  135. * 
  136. *********************************************************************
  137. #endcomment
  138.  
  139. proc getmailbox
  140. PermRadio = 1
  141. GetSendRadio = 1
  142. destroydlg
  143. HelpPage = 8
  144. dialogbox 52 68 243 93 15 "Get/Send Mail" HELPID HelpPage
  145.    radiobutton 16 44 54 14 "Get Mail" GetSendRadio
  146.    radiobutton 16 63 54 14 "Send Mail" endgroup
  147.    radiobutton 94 44 54 14 "Permanent" PermRadio
  148.    radiobutton 94 63 54 14 "Temporary" endgroup
  149.    pushbutton 184 44 40 14 "&Add" normal default
  150.    pushbutton 184 63 40 14 "&Done" normal
  151.    text  52 12 68 8 right "Get/Send Mail for:"
  152.    combobox 124 10 67 41 BBSList BBS sort
  153. enddialog
  154. endproc
  155.  
  156.  
  157. #comment
  158. *********************************************************************
  159. * 
  160. * ADDSENDCOMMAND()
  161. * 
  162. * Called by main()
  163. * 
  164. * Calls getbbsi(), getitemi(), getbbscoord(), getitemcoord(),
  165. * gettaskstring(), makebbslist(), interfaceon(),
  166. * sendcommandbox(), checkperm(), insertitem()
  167. * 
  168. * Adds a "SendCommand" item to the mailrun.  A command
  169. * string may contain multiple command lines separated by
  170. * verticle bars.  Successive command lines will be sent
  171. * when the terminal screen is quiet for 15 seconds.
  172. * 
  173. *********************************************************************
  174. #endcomment
  175.  
  176. proc addsendcommand
  177. string CommandString, StatString
  178. string Perm
  179. integer dialogstatus
  180. integer i, j
  181.     i = getbbsi()
  182.     j = getitemi()
  183.     makebbslist()
  184.     sendcommandbox()
  185.     statmsg ""
  186.     interfaceon()
  187.     while 1
  188.         dialogstatus = $DIALOG
  189.         switch dialogstatus
  190.             case 10
  191.                 ;User selected "Add"
  192.                 Perm = checkperm()
  193.                 strfmt CommandString "1,%s,SendCommand,%s" Perm Command
  194.                 strfmt StatString "Added to %s:  `"Send Command:  %s`"" \
  195.                     BBS Command
  196.                 j++
  197.                 insertitem(j, CommandString)
  198.                 TaskItem = gettaskstring(i, j)
  199.                 statmsg StatString
  200.             endcase
  201.             case 11
  202.                 ;User selected "Done"
  203.                 exit
  204.             endcase
  205.             case 170
  206.                 ;User changed BBS with the combobox
  207.                 i = getbbscoord()
  208.                 j = getitemcoord()
  209.                 TaskItem = gettaskstring(i, 0)
  210.             endcase
  211.         endswitch
  212.     endwhile
  213. endproc
  214.  
  215.  
  216. #comment
  217. *********************************************************************
  218. * 
  219. * SENDCOMMANDBOX()
  220. * 
  221. * Called by addsendcommand()
  222. * 
  223. * Displays the Send Command dialog box.
  224. * 
  225. *********************************************************************
  226. #endcomment
  227.  
  228. proc sendcommandbox
  229. PermRadio = 2
  230. Command = ""
  231. destroydlg
  232. HelpPage = 11
  233. dialogbox 92 63 196 124 15 "Send Command" HELPID HelpPage
  234.    text  8 39 42 8 right "Command:"
  235.    editbox 54 37 124 11 Command
  236.    radiobutton 32 85 59 11 "Permanent" PermRadio
  237.    radiobutton 32 101 59 11 "Temporary" endgroup
  238.    pushbutton 129 77 40 14 "&Add" normal default
  239.    pushbutton 129 97 40 14 "&Done" normal
  240.    text  30 15 68 8 right "Send Command to:"
  241.    combobox 102 13 65 42 BBSList BBS sort
  242.    text  54 51 97 8 left "Use a vertical bar (`"|`") to"
  243.    text  54 61 97 8 left "separate multiple commands."
  244. enddialog
  245. endproc
  246.  
  247.  
  248. #comment
  249. *********************************************************************
  250. * 
  251. * ADDDOSCRIPT()
  252. * 
  253. * Called by main()
  254. * 
  255. * Calls getbbsi(), getitemi(), getbbscoord(), getitemcoord(),
  256. * makebbslist(), makescriptlist(), interfaceon(),
  257. * gettaskstring(), scriptbox(), checkperm(), insertitem()
  258. * 
  259. * Adds a SendScript Item to the mailrun.
  260. * 
  261. *********************************************************************
  262. #endcomment
  263.  
  264. proc adddoscript
  265. string ScriptString, StatString
  266. string Perm
  267. integer dialogstatus
  268. integer i, j
  269.     i = getbbsi()
  270.     j = getitemi()
  271.     makebbslist()
  272.     makescriptlist()
  273.     scriptbox()
  274.     statmsg ""
  275.     interfaceon()
  276.     while dialogstatus != 1
  277.         dialogstatus = $DIALOG
  278.         switch dialogstatus
  279.             case 10
  280.                 ;User chose "Add"
  281.                 Perm = checkperm()
  282.                 strupr ScriptName
  283.                 strfmt ScriptString "1,%s,SendScript,%s" Perm ScriptName
  284.                 strfmt StatString "Added to %s:  `"Execute Script:  %s`"" \
  285.                     BBS ScriptName
  286.                 j++
  287.                 insertitem(j, ScriptString)
  288.                 TaskItem = gettaskstring(i, j)
  289.                 statmsg StatString
  290.             endcase
  291.             case 11
  292.                 ;User selected "Done"
  293.                 exit
  294.             endcase
  295.             case 170
  296.                 ;User changed BBS with the combobox
  297.                 i = getbbscoord()
  298.                 j = getitemcoord()
  299.                 TaskItem = gettaskstring(i, 0)
  300.             endcase
  301.         endswitch
  302.     endwhile
  303. endproc
  304.  
  305.  
  306. #comment
  307. *********************************************************************
  308. * 
  309. * MAKESCRIPTLIST()
  310. * 
  311. * Called by adddoscript()
  312. * 
  313. * Calls openfile(), makefullname()
  314. * 
  315. * Creates a list of scripts for display in the scriptbox()
  316. * dialog box script fcombobox.
  317. * 
  318. *********************************************************************
  319. #endcomment
  320.  
  321. proc makescriptlist
  322. string ScriptSpec, NextScript, ScriptLine
  323.     ScriptName = ""
  324.     ScriptList = makefullname(TempDir, "SCRIPTS.TMP")
  325.     openfile(ScriptFile, ScriptList, _CREATE, _TEXT)
  326.     ScriptSpec = makefullname(MailRunDir, "*.WA?")
  327.     findfirst ScriptSpec
  328.     ;Loop through all files in the directory
  329.     while FOUND
  330.         NextScript = $FNAME
  331.         strlwr NextScript
  332.         switch NextScript
  333.             case "MRUN210"
  334.             case "MRUN210A"
  335.             case "MRUN210B"
  336.             case "MRUN210C"
  337.             case "MRUN210D"
  338.             case "MRUN210E"
  339.             case "MRUN210F"
  340.             case "MRUN210G"
  341.             case "ARRAY"
  342.             case "HOST"
  343.             case "HOSTUTIL"
  344.             case "USER"
  345.             case "SUBS"
  346.             case "MAIL"
  347.             endcase
  348.             default
  349.                 rewind ScriptFile
  350.                 fgets ScriptFile ScriptLine
  351.                 while not NULLSTR ScriptLine
  352.                     if strcmp ScriptLine NextScript
  353.                         exitswitch
  354.                     endif
  355.                     fgets ScriptFile ScriptLine
  356.                 endwhile
  357.                 fputs ScriptFile NextScript
  358.                 if NULLSTR ScriptName
  359.                     ScriptName = NextScript
  360.                 endif
  361.             endcase
  362.         endswitch
  363.         findnext
  364.     endwhile
  365.     fclose ScriptFile
  366. endproc
  367.  
  368.  
  369. #comment
  370. *********************************************************************
  371. * 
  372. * SCRIPTBOX()
  373. * 
  374. * Called by adddoscript()
  375. * 
  376. * Displays the Execute Script dialog box.
  377. * 
  378. *********************************************************************
  379. #endcomment
  380.  
  381. proc scriptbox
  382. PermRadio = 2
  383. destroydlg
  384. ScriptName = "terminal"
  385. HelpPage = 12
  386. dialogbox 92 60 180 135 15 "Execute Script" HELPID HelpPage
  387.    text  14 36 64 8 right "Available Scripts:"
  388.    fcombobox 82 34 76 42 ScriptList ScriptName sort
  389.    text  20 54 136 22 left "WARNING:  Scripts must not alter \
  390. global variables s0-s9 and i0-i9!!!"
  391.    radiobutton 17 85 62 14 "Permanent" PermRadio
  392.    radiobutton 17 107 62 14 "Temporary" endgroup
  393.    pushbutton 114 85 40 14 "&Add" normal default
  394.    pushbutton 114 107 40 14 "&Done" normal
  395.    text  14 11 64 8 right "Execute Script at:"
  396.    combobox 82 9 76 42 BBSList BBS sort
  397. enddialog
  398. endproc
  399.  
  400.  
  401. #comment
  402. *********************************************************************
  403. * 
  404. * SHOWABOUT()
  405. * 
  406. * Called by main()
  407. * 
  408. * Calls aboutbox()
  409. * 
  410. * Displays the About MailRun dialog box.
  411. * 
  412. *********************************************************************
  413. #endcomment
  414.  
  415. proc showabout
  416. integer dialogstatus
  417.     statmsg ""
  418.     aboutbox()
  419.     dialogstatus = $DIALOG
  420.     while dialogstatus != 1
  421.         dialogstatus = $DIALOG
  422.     endwhile
  423.     exit
  424. endproc
  425.  
  426.  
  427. #comment
  428. *********************************************************************
  429. * 
  430. * ABOUTBOX()
  431. * 
  432. * Called by showabout()
  433. * 
  434. * Calls makefullname()
  435. * 
  436. * Displays the About MailRun dialog box.
  437. * 
  438. *********************************************************************
  439. #endcomment
  440.  
  441. proc aboutbox
  442. destroydlg
  443. HelpPage = 1
  444. MRunIcons = makefullname(MailRunDir, "MRUNICON.DLL")
  445. IconIndex = 17
  446. dialogbox 55 55 220 151 15 "About MailRun" HELPID HelpPage
  447.    text  42 14 136 27 center "MailRun`r`nVersion 2.10`r`n\
  448. Copyright ⌐ 1992-1993 Gerald P. Sully"
  449.    text  20 48 180 28 left "If you use MailRun with any regularity, \
  450. ease your aching conscience by helping out a starving author.`r`n\
  451. Send $15 to:"
  452.    icon 160 82 MRunIcons IconIndex
  453.    text  20 80 120 44 left "Jerry Sully`r`n841 Solano Ave. #2`r`n\
  454. Albany, CA  94706`r`n`r`nThank you for your support!"
  455.    pushbutton 20 128 180 12 "I promise I'll send $15 as soon as I \
  456. can afford it!" cancel
  457. enddialog
  458. endproc
  459.